blob: 8e24a801a02e39bab54f7fd3d319d0cf69460cf7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Riolku <me [at] kgugeler [dot] ca>
pkgname=kambi
pkgver=0.1.1
pkgrel=1
pkgdesc='Simple rotating wallpaper client for Wayland'
arch=('x86_64')
url="https://git.sr.ht/~riolku/$pkgname"
license=('MIT')
depends=('gcc-libs' 'glibc')
makedepends=('cargo' 'scdoc')
provides=("$pkgname")
conflicts=('kambi-git')
source=("$url/archive/v$pkgver.tar.gz")
sha256sums=('b551db3cb4ef5a30969b683e96252929329d421386b7412ac4fbfb4202f29f1b')
prepare() {
cd "$srcdir/$pkgname-v$pkgver"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$srcdir/$pkgname-v$pkgver"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --release --locked
scdoc < man/kambi.5.scd > man/kambi.5
}
package() {
cd "$srcdir/$pkgname-v$pkgver"
install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/kambi"
install -Dm0755 -t "$pkgdir/usr/share/man/man5" "man/kambi.5"
}
|