PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: beelzy
pkgname=kame-tools-git
pkgver=90ca8e5
pkgrel=1
pkgdesc="A tool for bundling 3DS theme files"
arch=('i686' 'x86_64' 'aarch64')
url="https://gitlab.com/beelzy/kame-tools"
license=('MIT')
makedepends=('git' 'zip')
depends=('gcc-libs')

_gitroot='https://gitlab.com/beelzy/kame-tools.git'
_gitname='kame-tools'

source=("git+${_gitroot}"
        "git+https://github.com/lifehackerhansol/buildtools.git")
sha256sums=('SKIP' 'SKIP')

pkgver() {
    cd "$srcdir/$_gitname"
    git log --pretty=format:"%h" -1
}

prepare() {
    cd "$srcdir/$_gitname"
    git submodule init
    git config submodule.buildtools.url $srcdir/buildtools
    git submodule sync
    git -c protocol.file.allow=always submodule update --force
    cd buildtools
    git apply ../aarch64.patch
}

build() {
    cd "$srcdir/$_gitname"
    make BUILD_FLAGS="$LDFLAGS"
}

package() {
    install -D "$srcdir/$_gitname/output/linux-$CARCH/kame-tools" "$pkgdir/usr/bin/kame-tools"
    install -Dm644 "$srcdir/$_gitname/LICENSE.txt" "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}