PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: SandaruKasa <sandarukasa plus aur at ya dot ru>

pkgname=kani-verifier
pkgver=0.51.0
pkgrel=1
pkgdesc='Bit-precise model checker for Rust'
arch=('x86_64' 'aarch64')
url="https://github.com/model-checking/kani"
license=("Apache-2.0 OR MIT")
makedepends=(rust cargo coreutils sed gcc)
depends=(gcc-libs glibc)
provides=(kani cargo-kani)
conflicts=(kani cargo-kani)
source=("$pkgname-$pkgver.tar.gz::https://static.crates.io/crates/$pkgname/$pkgname-$pkgver.crate")
sha256sums=('072652a7825ef9cb0b1a30a170bef1ee94f9aaa4773de5c95ee6d4cbec9d8989')
_src="${pkgname}-${pkgver}"

prepare() {
  cd "${_src}"
  rm -f rust-toolchain.toml
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}


build() {
  cd "${_src}" 
  export CARGO_TARGET_DIR=./target
  cargo build --frozen --release --all-features
}

check() {
  cd "${_src}"
  cargo test --frozen --all-features
}

package() {
  cd "${_src}"

  find target/release \
    -maxdepth 1 \
    -executable \
    -type f \
    -exec install -Dm0755 -t "$pkgdir/usr/bin/" {} +

  install -Dm644 LICENSE-MIT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-MIT"
  install -Dm644 LICENSE-APACHE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-APACHE"
}