PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85

# Maintainer: leonekmi <usingarchbtw@leonekmi.fr>
pkgname=karaokemugen
pkgver=9.0.41
pkgrel=1
pkgdesc="Karaoke playlist manager/player app used in parties or events."
arch=('x86_64')
url="https://mugen.karaokes.moe/"
license=('MIT')
groups=()
depends=('mpv' 'ffmpeg' 'postgresql' 'electron39')
makedepends=('git' 'npm' 'typescript' 'corepack')
provides=("${pkgname}")
conflicts=("${pkgname}")
replaces=()
backup=()
options=()
install=${pkgname}.install
source=("${pkgname}::git+https://gitlab.com/karaokemugen/code/karaokemugen-app.git#tag=9.0.41"
        "${pkgname}-lib::git+https://gitlab.com/karaokemugen/code/lib.git"
        "${pkgname}-guests::git+https://gitlab.com/karaokemugen/medias/guest-avatars.git"
        "${pkgname}-systemRepo::git+https://gitlab.com/karaokemugen/bases/system.git"
        'install.sh'
        'run.sh'
        'icon256.png'
        'karaokemugen.desktop')
noextract=()
md5sums=('384528f05d202552b8257866a63eb64b'
         'SKIP'
         'SKIP'
         'SKIP'
         '2548b70d012d3992526c8d5b1d9bac3d'
         'd17324cd29097a809b89a5ea93efaf34'
         '5e9a33a42fef7572b7e0fa504c586f32'
         'fae5d3e631e9ec8391655b31f586b74b')

prepare() {
    cd "$srcdir/${pkgname}"
    git submodule init
    git config submodule.src/lib.url "$srcdir/${pkgname}-lib"
    git config submodule.assets/guestAvatars.url "$srcdir/${pkgname}-guests"
    git config submodule.assets/systemRepo.url "$srcdir/${pkgname}-systemRepo"
    git -c protocol.file.allow=always submodule update
}

build() {
    cd "$srcdir/${pkgname}"
    # Prepare dependencies
    export HOME="$srcdir/$pkgname-home"
    export COREPACK_HOME="$srcdir/$pkgname-corepack-cache"
    export XDG_CACHE_HOME="$srcdir/$pkgname-cache"
    export npm_config_cache="$srcdir/$pkgname-npm-cache"
    corepack yarn install
    corepack yarn setup

    # Build and package with electron-builder
    export NODE_ENV='production'
    electronDist=$(dirname $(realpath $(which electron)))
    electronVer=$(electron --version | tail -c +2)

    corepack yarn packer
}

package() {
    cd "$srcdir/${pkgname}"

    # Application itself
    install -dm 755 "$pkgdir/usr/lib/${pkgname%-git}"
    cp -dr --no-preserve=ownership packages/linux-unpacked/resources/* "$pkgdir/usr/lib/${pkgname%-git}/"
    chmod -R 755 "$pkgdir/usr/lib/${pkgname%-git}/"

    # License
    install -dm 755 "$pkgdir/usr/share/licenses/${pkgname%-git}"
    install -m 644 LICENSE.md "$pkgdir/usr/share/licenses/${pkgname%-git}/LICENSE"

    # Runtimes
    install -dm 755 "$pkgdir/usr/bin/"
    install -m 755 "$srcdir/run.sh" "$pkgdir/usr/bin/karaokemugen"
    install -m 755 "$srcdir/install.sh" "$pkgdir/usr/bin/karaokemugen-install"

    # .desktop entry
    install -dm 755 "$pkgdir/usr/share/pixmaps/"
    install -dm 755 "$pkgdir/usr/share/applications/"
    install -m 644 "$srcdir/icon256.png" "$pkgdir/usr/share/pixmaps/${pkgname%-git}.png"
    install -m 644 "$srcdir/${pkgname%-git}.desktop" "$pkgdir/usr/share/applications/${pkgname%-git}.desktop"
}