blob: b91635e0c6a17f5f9c64f5d8a56422874b63a101 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Louis Solofrizzo <louis@ne02ptzero.me>
_pkgname=kart
pkgname="${_pkgname}-git"
pkgver=0.2.0.r3.gf26bb48
pkgrel=1
pkgdesc="Internet Art crawler"
arch=("i686" "x86_64" "arm" "armv6h" "armv7h" "aarch64")
url="https://git.mobley.ne02ptzero.me/~louis/kart"
license=("GPL3")
makedepends=("cmake" "git" "go")
optdepends=("vlc" "feh" "sxiv")
provides=("kart")
conflicts=("kart")
source=("${_pkgname}::git+${url}")
md5sums=("SKIP")
pkgver() {
git -C "${_pkgname}" describe --long --tags | sed "s/-/.r/;s/-/./g"
}
prepare() {
git -C "${_pkgname}" submodule update --init --recursive
mkdir -p "${_pkgname}/build"
}
build() {
cd "${_pkgname}/build" || exit 1
cmake -DCMAKE_INSTALL_PREFIX=/usr ..
cmake --build .
}
package() {
cmake --build "${_pkgname}/build" --target install -- DESTDIR="${pkgdir}"
install -Dm644 "${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}
|