PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Author: futpib <futpib@gmail.com>

_gitname=kded_rotation
pkgname=kded-rotation-git
pkgver=r26.fac175b
pkgrel=1
pkgdesc='KDED module for handling automatic screen rotation (WIP) '
arch=(i686 x86_64)
url='https://github.com/dos1/kded_rotation'
license=(GPL2 GPL3)
depends=(kded iio-sensor-proxy xorg-xrandr xorg-xinput qt5-sensors)
makedepends=(extra-cmake-modules git)
conflicts=()
source=("git+https://github.com/dos1/$_gitname.git")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$_gitname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
  # Fix CMakeLists.txt for newer CMake versions
  cd "$srcdir/$_gitname"
  sed -i '1s/^project.*$/cmake_minimum_required(VERSION 3.5 FATAL_ERROR)\n\nproject(kded_rotation)/' CMakeLists.txt
  sed -i '/^cmake_minimum_required(VERSION 2.8.12/d' CMakeLists.txt
}

build() {
  cd build
  cmake ../$_gitname \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DLIB_INSTALL_DIR=lib \
    -DLIBEXEC_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
  chmod +x "$pkgdir"/usr/bin/*
}