PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Maintainer:

_pkgname="kdisplay"
pkgname="$_pkgname"
pkgver=6.0.0
pkgrel=1
pkgdesc='Display management app and daemon (kwinft)'
url="https://github.com/winft/kdisplay"
license=('LGPL-2.1-only')
arch=('x86_64' 'aarch64')

depends=(
  kdeclarative
  layer-shell-qt
  libplasma
  plasma5support
  qt6-sensors

  # AUR
  disman

  ## implicit
  #kcmutils
  #kconfig
  #kcoreaddons
  #kdbusaddons
  #kglobalaccel
  #ki18n
  #kirigami
  #ksvg
  #kwindowsystem
  #kxmlgui
  #qt6-declarative
)
makedepends=(
  extra-cmake-modules
  git
  ninja
)

provides=("kscreen=$pkgver")
conflicts=("kscreen")

_pkgsrc="$_pkgname-$pkgver"
_pkgext="tar.gz"
source=("$_pkgsrc.$_pkgext"::"$url/archive/refs/tags/v$pkgver.$_pkgext")
sha256sums=('b1da715f9eb0cffb116ea9d0f756668da96848db562b4a2de5a524f321759537')

build() {
  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -DBUILD_TESTING=OFF
    -Wno-dev
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}