blob: 1121826f03fdc71fb2e76dd6951cdcf7a68c2039 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=keep-me-awake
_app_id=de.swsnr.keepmeawake
pkgver=2.1.4
pkgrel=1
pkgdesc="Inhibit screensaver and suspend in GNOME"
arch=('any')
url="https://codeberg.org/swsnr/keep-me-awake"
license=('EUPL-1.2')
depends=(
'gtk4'
'libadwaita'
'libportal'
'libportal-gtk4'
'python-gobject'
'python-packaging'
)
makedepends=(
'blueprint-compiler'
'git'
'python-build'
'python-hatchling'
'python-installer'
'python-wheel'
)
source=("git+https://codeberg.org/swsnr/keep-me-awake.git#tag=v$pkgver")
sha256sums=('03cce57ede07170978120cf6ef6cd36b363adf89c6bdf972d13d50ac635e08e3')
build() {
cd "$pkgname"
# Skip dependency check as it can't find blueprint-compiler
# even though we have it
python -m build --wheel --skip-dependency-check --no-isolation
}
check() {
cd "$pkgname"
appstreamcli validate --no-net "${_app_id}.metainfo.xml"
desktop-file-validate "${_app_id}.desktop"
}
package() {
cd "$pkgname"
python -m installer --destdir="$pkgdir" dist/*.whl
ln -s "/usr/bin/${_app_id}" "$pkgdir/usr/bin/$pkgname"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|