summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6286be11aa8cfe9a3b6f10a6093388d205f6f435 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: lmartinez-mirror
pkgname=kiro-git
pkgver=0.4.3.r3.g4ba92af
pkgrel=1
pkgdesc="A tiny UTF-8 text editor"
arch=('x86_64')
url="https://github.com/rhysd/kiro-editor"
license=('MIT')
depends=('gcc-libs')
makedepends=('git' 'cargo')
provides=('kiro')
conflicts=('kiro')
source=("$pkgname::git+$url")
md5sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
}

build() {
  cd "$pkgname"
  cargo build --release --locked --all-features --target-dir=target
}

check() {
  cd "$pkgname"
  cargo test --release --locked --target-dir=target
}

package() {
  cd "$pkgname"
  install -Dm 755 target/release/kiro -t "$pkgdir/usr/bin/"
  install -Dm 644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}