blob: 01b806270845be593caf9cd85cc58cd355c8c376 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
# Maintainer: solsTiCe d'Hiver <solstice.dhiver@gmail.com>
# Contributor: dreieck (https://aur.archlinux.org/account/dreieck)
# Contributor: Alexander Paetzelt <techge+arch [ät] posteo [do] net>
pkgname=kismet-git
pkgver=2025_11_R0.r12232
pkgrel=1
pkgdesc="a sniffer, WIDS, and wardriving tool for Wi-Fi, Bluetooth, Zigbee, RF"
url="https://www.kismetwireless.net/"
arch=('x86_64' 'armv7h' 'aarch64' 'i686')
license=('GPL-2.0-or-later')
depends=('bluez-libs'
'gcc-libs'
'glibc'
'libcap'
'libelf'
'libnl'
'libnm'
'libcap-ng'
'libpcap'
'libusb'
'libwebsockets'
'lm_sensors'
'mosquitto'
'pcre2'
'rtl-sdr'
'sqlite'
'systemd'
'zlib')
makedepends=('git')
optdepends=('festival: text-to-speech support'
'flite: alternative/lightweight text-to-speech support'
'gpsd: log coordinates of detected networks'
'hackrf: use with HackRF compatible software defined radio (SDR)'
'sox: provide the default kismet sound playback binary'
'wireshark-cli: mergecap, to merge multiple capture files',
'libbtbb: bluetooth baseband decoding library')
backup=(etc/kismet/kismet.conf
etc/kismet/kismet_80211.conf
etc/kismet/kismet_alerts.conf
etc/kismet/kismet_filter.conf
etc/kismet/kismet_httpd.conf
etc/kismet/kismet_logging.conf
etc/kismet/kismet_memory.conf
etc/kismet/kismet_uav.conf
etc/kismet/kismet_wardrive.conf)
provides=('kismet')
conflicts=('kismet')
install="${pkgname}.install"
source=("git+https://github.com/kismetwireless/kismet"
"${pkgname}-sysusers.conf")
sha256sums=('SKIP'
'0ac08bf5016e00596e2fc0bc89e7907c2186b811ed8d8a2bffe6b95b42e147a3')
pkgver() {
cd "$srcdir/kismet"
# instead of running tools/mkversion.sh just use the current month and year
_ver="$(date '+%Y')_$(date '+%m')_R0"
_rev="$(git rev-list --count HEAD)"
# falling back to revision and HEAD commit
#_head="$(git rev-parse --short HEAD)"
#printf '%s' "r${_rev}.${_head}"
printf '%s' "${_ver}.r${_rev}"
}
prepare() {
cd "$srcdir/kismet"
autoreconf -fiv
}
build() {
cd "$srcdir/kismet"
./configure --prefix=/usr \
--localstatedir=/var \
--sysconfdir=/etc/kismet \
--with-suidgroup=315
make all plugins
}
package() {
cd "$srcdir/kismet"
make DESTDIR="$pkgdir/" install
# install systemd service
install -vDm 644 "packaging/systemd/kismet.service" "${pkgdir}/usr/lib/system/systemd/kismet.service"
# Makepkg strip bug #43600
chmod u+w "${pkgdir}"/usr/bin/kismet*
chmod o-x "${pkgdir}"/usr/bin/kismet_cap*
chown 0:315 "${pkgdir}"/usr/bin/kismet_cap*
install -vDm 644 -t "${pkgdir}/usr/share/doc/kismet" README.md README.SSL
# create group kismet via sysusers
cd "$srcdir"
install -vDm 644 "${pkgname}-sysusers.conf" "${pkgdir}/usr/lib/sysusers.d/kismet.conf"
}
# vim: set ts=4 sw=4 et:
|