blob: d5c00a3d15713d1f26e7580cc2713da202ce92d2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer:
# Contributor: Kazel <address at domain dot tld>
_pkgname="klevernotes"
pkgname="$_pkgname"
pkgver=1.2.5
pkgrel=1
pkgdesc="A convergent markdown note taking application"
url="https://invent.kde.org/office/klevernotes"
license=('GPL-2.0-or-later' 'LGPL-2.1-or-later')
arch=('x86_64')
depends=(
'hicolor-icon-theme'
'kcolorscheme'
'kconfig'
'kcoreaddons'
'ki18n'
'kiconthemes'
'kio'
'kirigami'
'kirigami-addons'
'kitemmodels'
'qt6-base'
'qt6-declarative'
'qt6-webchannel'
'qt6-webengine'
)
makedepends=(
'cmake'
'extra-cmake-modules'
'ninja'
)
checkdepends=(
'weston'
'wlheadless-run' # aur/xwayland-run
)
_pkgsrc="$_pkgname-v$pkgver"
_pkgext="tar.gz"
source=("$_pkgname-$pkgver.$_pkgext"::"$url/-/archive/v${pkgver}/$_pkgsrc.$_pkgext")
sha256sums=('d9cf47f89f81e4f76b5d867abea11f15063c12863ad2bab51a198acd1aacaf89')
build() {
local _cmake_options=(
-B build
-S "$_pkgsrc"
-G Ninja
-DCMAKE_BUILD_TYPE=None
-DCMAKE_INSTALL_PREFIX='/usr'
-DBUILD_TESTING=$CHECKFUNC
-Wno-dev
)
cmake "${_cmake_options[@]}"
cmake --build build
}
check() {
local _headless_run=(
wlheadless-run
-c weston --width=1920 --height=1080
)
env "${_headless_run[@]}" -- ctest --test-dir build --rerun-failed --output-on-failure
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
|