PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer: tippfehlr <tippfehlr@tippfehlr.dev>
# Contributor: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Laurent Carlier <lordheavym@gmail.com>
# Contributor: Vamp898 <vamp898@web.de>
# Contributor: Jaroslaw Swierczynski <swiergot@aur.archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Todd Maynard <arch@toddmaynard.com>

pkgname=kmymoney-git
pkgver=5.1.95.r572.gcc9596c
pkgrel=1
pkgdesc="Personal finance manager for KDE which operates similarly to MS-Money or Quicken"
arch=('x86_64')
url="https://kmymoney.org/"
license=('GPL-2.0-or-later')
depends=(
	'glibc' 'gcc-libs' 'gmp' 'libalkimia' 'sqlcipher' 'qt6-base' 'gpgmepp'
	'karchive' 'kcoreaddons' 'kconfig' 'kwidgetsaddons' 'ki18n'
	'kcompletion' 'kcmutils' 'kitemmodels' 'kitemviews' 'kxmlgui'
	'ktextwidgets' 'kio' 'kholidays' 'kjobwidgets' 'sonnet' 'kcolorscheme'
	'kconfigwidgets' 'kdiagram' 'libical' 'libofx' 'qtkeychain-qt6'
	'kidentitymanagement' 'libakonadi' 'kcontacts' 'aqbanking' 'gwenhywfar'
	'qt6-declarative' 'hicolor-icon-theme' 'kcrash'
)
makedepends=('cmake' 'extra-cmake-modules' 'kdoctools' 'doxygen' 'qgpgme' 'git')
optdepends=(
	'perl: for financequote.pl'
	'python: for the woob plugin'
)
provides=('kmymoney')
conflicts=('kmymoney')
source=('git+https://invent.kde.org/office/kmymoney.git')
sha256sums=('SKIP')

pkgver() {
	cd kmymoney
	git describe --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	local cmake_options=(
		-B build
		-S kmymoney
		-W no-dev
		-D CMAKE_BUILD_TYPE=None
		-D CMAKE_INSTALL_PREFIX=/usr
		-D BUILD_WITH_QT6=ON
		-D CMAKE_SKIP_RPATH=YES
		-D BUILD_TESTING=OFF
	)
	cmake "${cmake_options[@]}"
	cmake --build build
}

package() {
	DESTDIR="$pkgdir" cmake --install build
}