summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: a1a23baafed318736262d4decfd58c83493427bf (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Merged with official ABS kross PKGBUILD by João, 2021/02/01 (all respective contributors apply herein)
# Maintainer: João Figueiredo & chaotic-aur <islandc0der@chaotic.cx>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=kross-git
pkgver=5.116.0_r472.gd793798
pkgrel=1
pkgdesc='Multi-language application scripting'
arch=($CARCH)
url='https://community.kde.org/Frameworks'
license=(LGPL)
depends=(kparts5 qt5-script)
makedepends=(git extra-cmake-modules-git kdoctools5 qt5-tools)
conflicts=(${pkgname%-git})
provides=(${pkgname%-git})
groups=(kf5-aids-git)
source=("git+https://github.com/KDE/${pkgname%-git}.git")
sha256sums=('SKIP')

prepare() {
  cd ${pkgname%-git}
  git checkout kf5
}

pkgver() {
  cd ${pkgname%-git}
  _ver="$(grep -m1 'set(KF5\?_VERSION' CMakeLists.txt | cut -d '"' -f2 | tr - .)"
  echo "${_ver}_r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)"
}

build() {
  cmake -B build -S ${pkgname%-git} \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}