blob: f567d5427d4981d1782da1318a1a4245917c45e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: tarball <bootctl@gmail.com>
pkgname=ktailctl
pkgver=0.16.0
pkgrel=1
arch=(x86_64 aarch64)
url='https://github.com/f-koehler/KTailctl'
pkgdesc='GUI to monitor and manage Tailscale'
license=(GPL-3.0-only)
depends=(
gcc-libs
glibc
hicolor-icon-theme
kconfig
kcoreaddons
kguiaddons
ki18n
kirigami
kirigami-addons
knotifications
nlohmann-json
qt6-base
qt6-declarative
qt6-svg
tailscale
)
makedepends=(cmake extra-cmake-modules go)
# git tag is used by the cmake script to determine app version
source=(git+$url.git#tag=v$pkgver)
sha256sums=('17e37f1acabfb2ec90032b8f94eca67a03e322a030a039537b0ce260d65a01de')
prepare() {
cd KTailctl/tailwrap
go mod vendor
}
build() {
cmake -B build -S KTailctl \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
|