PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Daniel Bermond < gmail-com: danielbermond >

pkgname=kvazaar
pkgver=1.3.0
pkgrel=1
pkgdesc='An open-source HEVC encoder'
arch=('x86_64')
url='http://ultravideo.cs.tut.fi/#encoder'
license=('LGPL')
depends=('glibc' 'gcc-libs' 'crypto++')
makedepends=('git' 'yasm')
checkdepends=('ffmpeg' 'hm')
source=("git+https://github.com/ultravideo/kvazaar.git#tag=v${pkgver}"
        'git+https://github.com/ultravideo/greatest.git')
sha256sums=('SKIP'
            'SKIP')

prepare() {
    cd kvazaar
    
    git submodule init
    git config --local submodule.greatest.url "${srcdir}/greatest"
    git submodule update
    
    ./autogen.sh
}

build() {
    cd kvazaar
    
    ./configure \
        --prefix='/usr' \
        --with-cryptopp
        
    make
}

check() {
    cd kvazaar
    
    make check
}

package() {
    cd kvazaar
    
    make DESTDIR="$pkgdir" install
}