PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Maintainer: Nixugea
# Maintainer: holybaechu <holyb@holyb.xyz>

# As of 1.0.32, the hash check is skipped.
pkgname=labymod-appimage
pkgver=2.1.2
pkgrel=2
pkgdesc='LabyMod Launcher for launching LabyMod, which is a Minecraft client that adds bunch of useful features (This is an unofficial package)'
url=https://www.labymod.net
arch=(x86_64)
license=(proprietary)
options=(!strip !debug)
source=("https://releases.r2.labymod.net/launcher/linux/x64/LabyMod%20Launcher-${pkgver}.AppImage")
sha256sums=('SKIP')
depends=(fuse xorg-xrandr imagemagick)

_pkgname=labymodlauncher
_appimage="LabyMod%20Launcher-${pkgver}.AppImage"

prepare() {
        chmod +x "${_appimage}"
        ./"${_appimage}" --appimage-extract
}

build() {
        # Adjust .desktop so it will work outside of AppImage container
        sed -i -E \
                "s|Exec=AppRun|Exec=env DESKTOPINTEGRATION=false /usr/bin/${_pkgname}|" \
                "squashfs-root/${_pkgname}.desktop"
        # Fix permissions; .AppImage permissions are 700 for all directories
        chmod -R a-x+rX squashfs-root/usr
}

package() {
        mkdir -p "${pkgdir}/opt/${_pkgname}"

        # AppImage
        install -Dm755 \
                "${srcdir}/${_appimage}" \
                "${pkgdir}/opt/${_pkgname}/${_pkgname}.AppImage"

        # Desktop file
        install -Dm644 \
 		"${srcdir}/squashfs-root/${_pkgname}.desktop" \
 		"${pkgdir}/usr/share/applications/${_pkgname}.desktop"

        # Replace default Electron icons with LabyMod icons
        resolutions="16x16 32x32 48x48 64x64 128x128 256x256"
        for resolution in $resolutions; do
                convert -resize $resolution \
                        "${srcdir}/squashfs-root/resources/icons/icon.png" \
                        "${srcdir}/squashfs-root//usr/share/icons/hicolor/${resolution}/apps/${_pkgname}.png"
        done

        # Icon images
        install -dm755 "${pkgdir}/usr/share/"
	cp -a \
		"${srcdir}/squashfs-root/usr/share/icons" \
                "${pkgdir}/usr/share"
                
	# Symlink executable
        install -dm755 "${pkgdir}/usr/bin"
        ln -s \
                "/opt/${_pkgname}/${_pkgname}.AppImage" \
                "${pkgdir}/usr/bin/${_pkgname}"
}