blob: 45cd3e1b6849bb9972f2f02c717b32dbd0705c74 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Tim Schumacher <timschumi@gmx.de>
# Contributor: Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor: Brian <brain@derelict.garden>
pkgname=ladybird
pkgver=20240417
pkgrel=1
pkgdesc='Web browser built from scratch using the SerenityOS LibWeb engine'
arch=(x86_64)
url='https://github.com/SerenityOS/serenity'
license=(BSD)
depends=(brotli less libgl python qt6-base qt6-multimedia qt6-svg qt6-wayland)
makedepends=(cmake git ninja qt6-tools unzip)
options=(!lto !debug)
source=("git+$url#commit=c87e32154aac3a8942a44927f996887c398165fb" # 2024-04-17
"ladybird.desktop")
b2sums=('SKIP'
'SKIP')
build() {
cd "${srcdir}"
cmake \
-B build \
-S 'serenity/Ladybird' \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX='/usr' \
-GNinja \
-Wno-dev
ninja -C build
}
package() {
cd "${srcdir}"
DESTDIR="${pkgdir}" ninja -C build install
install -Dm644 "${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
install -Dm644 "serenity/Base/res/icons/32x32/app-browser.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
install -Dm644 serenity/LICENSE -t "${pkgdir}/usr/share/licenses/ladybird/"
}
|