blob: 9d451e53706ad2bcbcb66602aa46ffca632a234d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Rafael Dominiquini <rafaeldominiquini at gmail dot com>
_pkgauthor=Zouuup
_pkgname=landrun
pkgname=${_pkgname}-bin
pkgver=0.1.14
pkgrel=1
pkgdesc="Run any Linux process in a secure, unprivileged sandbox using Landlock LSM"
arch=('x86_64')
url="https://github.com/${_pkgauthor}/${_pkgname}"
_urlraw="https://raw.githubusercontent.com/${_pkgauthor}/${_pkgname}/v${pkgver}"
license=('MIT')
provides=("${_pkgname}")
conflicts=("${_pkgname}" "${_pkgname}-git")
makedepends=('help2man')
source=("LICENSE-${pkgver}::${_urlraw}/LICENSE"
"README-${pkgver}.md::${_urlraw}/README.md")
source_x86_64=("${_pkgname}-${pkgver}::${url}/releases/download/v${pkgver}/${_pkgname}-linux-amd64")
sha256sums=('f613c30920743111429f7c1cb801f49ccaafe8ae3319b3b0a5f8aca94e5fc082'
'1d355c7c297d5291fb6b5fa5d9ca2efbc9ce5e20f792246093ec435b522c3205')
sha256sums_x86_64=('645178e3239cd33760560834e50efea0864183a2a8a82faf199760dffee6dd71')
prepare() {
cd "${srcdir}/" || exit
chmod +x "./${_pkgname}-${pkgver}"
}
build() {
cd "${srcdir}/" || exit
help2man "./${_pkgname}-${pkgver}" --output "MAN-${pkgver}.1" --no-info
gzip "MAN-${pkgver}.1"
}
package() {
cd "${srcdir}/" || exit
install -Dm755 "${_pkgname}-${pkgver}" "${pkgdir}/usr/bin/${_pkgname}"
install -Dm644 "LICENSE-${pkgver}" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 "README-${pkgver}.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -Dm644 "MAN-${pkgver}.1.gz" "${pkgdir}/usr/share/man/man1/${_pkgname}.1.gz"
}
|