blob: e69e5d0e3e2f64c09631a4e545246d8045bada0d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Serge K <arch@phnx47.net>
# Contributor: Stephen Argent <steve [at] tuxcon [dot] com>
_pkgbin=ledger-live-desktop
_pkgname=ledger-live
pkgname="${_pkgname}-bin"
pkgdesc='Maintain your Ledger devices'
license=('MIT')
url='https://www.ledger.com/ledger-live'
pkgver=2.92.1
pkgrel=1
arch=('x86_64')
depends=('gtk3' 'nss' 'alsa-lib' 'ledger-udev')
options=('!strip')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
_appimg="ledger-live-desktop-${pkgver}-linux-${arch[0]}.AppImage"
source=("${_appimg}::https://download.live.ledger.com/${_appimg}"
"LICENSE-${pkgver}::https://raw.githubusercontent.com/LedgerHQ/ledger-live/%40ledgerhq/live-desktop%40${pkgver}/apps/ledger-live-desktop/LICENSE")
# https://www.ledger.com/ledger-live/lld-signatures
sha512sums=('eeff501b4141d9c6ef979200f065faa8f8f6a90c2c3e6e37d41806a594c559791c554517f79994b87c53b34b8a02a9d7291cb892889e73f451b3a4528b901f49'
'915edd51fe7732af57f5a4ca8f4c61c4f435de6357e34ed0733cac8d950d80b3a9e513deac0a3672a07f38ff871a57032a221b3aa27edae8e42cc00586fe3318')
prepare() {
chmod +x "${_appimg}"
"./${_appimg}" --appimage-extract
cd squashfs-root
sed -e "s/AppRun --no-sandbox/${_pkgbin}/g" -i "${_pkgbin}.desktop"
sed -e "/X-AppImage-Version/d" -i "${_pkgbin}.desktop"
rm "AppRun" "resources/app-update.yml"
}
package() {
install -d "${pkgdir}/opt/${_pkgname}"
cp -a "squashfs-root/." "${pkgdir}/opt/${_pkgname}/"
install -d "${pkgdir}/usr/bin"
ln -s "/opt/${_pkgname}/${_pkgbin}" "${pkgdir}/usr/bin/"
install -d "${pkgdir}/usr/share/applications"
ln -s "/opt/${_pkgname}/${_pkgbin}.desktop" "${pkgdir}/usr/share/applications/"
for i in 128 256 512 1024; do
install -d "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps"
ln -s "/opt/${_pkgname}/usr/share/icons/hicolor/${i}x${i}/apps/${_pkgbin}.png" "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/"
done
find "${pkgdir}" -type d -exec chmod 755 {} +
install -Dm644 "LICENSE-${pkgver}" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|