PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: Yukari Hafner <shinmera@tymoon.eu>
pkgname=lem-editor-git
pkgrel=1
pkgver=v2.1.0.645.gc44eba86
epoch=0
pkgdesc="An extensible editor written in Common Lisp"
arch=('i686' 'x86_64' 'aarch64')
url="https://github.com/lem-project/lem"
license=('MIT')
options=("!strip")
optdepends=('sdl2: Graphical client'
            'sdl2_ttf: Graphical client'
            'sdl2_image: Graphical client'
            'libdecor: Wayland support')
makedepends=('sbcl' 'sdl2' 'sdl2_ttf' 'sdl2_image' 'ncurses')
conflicts=('lem-editor')
provides=('lem-editor')
source=("lem::git+https://github.com/lem-project/lem"
        "installer"
        "general.lisp"
        "build-ncurses.lisp"
        "build-sdl2.lisp"
        "lem.desktop")
b2sums=('SKIP'
        'a235f8c3027b5656dba0666c87cb26a8980339aa3aaf62fe321392a200c3fd17776ca263d0e1ce975e3e3012f02064cf97a18b7e367acdf3dacb91c7f21cb5d1'
        'c228c6d9b3eb8379b40be04c7caef16698996642405dcbe769cbf3e8a09ff4464d4ed5638ff2cb12346a77cdf2e1f5eee42d7eb13aeb8f80d2f37c458ab82a6f'
        'c4302f39f5f916f5491f3816d95d60f93502eec4f2d3d8c75f69a464245ed252d89872d2997e907200bac15be39f064e6d69fe2213286dc60650f06fe28e1425'
        'a56e3dd69583c68f4c4e9b3e04c0ab80becd5e8ef98a2fbc7a7fe4aa27a4a6f4f98ff8dd814b1efbe144fdf59e7456fe707bf23095345bb60b198672418aff51'
        'ac7b40bcfdb2a4b6c49cd90914b9244215daf86ee99a390815c360d80c43be513a1a115d0aca4e07cbb81ea79ec8e452d15ff5e6b711d9b0b1b7e1b329124b41')

pkgver() {
    cd "$srcdir/lem"
    git describe | sed s/-/./g
}

prepare() {
    if [ ! -d "qlot" ]; then
        QLOT_HOME="$(pwd)/qlot" bash installer
    fi
}

build() {
    export PATH=$PATH:$(pwd)/qlot/bin/
    cd "$srcdir/lem"
    qlot install
    sbcl --noinform --no-sysinit --no-userinit --load .qlot/setup.lisp --load "$srcdir/build-ncurses.lisp"
    sbcl --noinform --no-sysinit --no-userinit --load .qlot/setup.lisp --load "$srcdir/build-sdl2.lisp"
}

package() {
    mkdir -p "$pkgdir/usr/bin/" "$pkgdir/usr/share/applications/" "$pkgdir/usr/share/lem"
    cp -r "$srcdir/lem/frontends/sdl2/resources" "$pkgdir/usr/share/lem/"
    cp "$srcdir/libasyncprocess.so" "$pkgdir/usr/share/lem/"
    cp "$srcdir/lem/lem" "$srcdir/lem/lem-gui" "$pkgdir/usr/bin/"
    cp "$srcdir/lem.desktop" "$pkgdir/usr/share/applications/"
}