PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Gordian Edenhofer <gordian.edenhofer@gmail.com>

pkgname=letshelp-certbot-git
_reponame="certbot"
pkgver=1.0.0.r23.gceea41c1e
pkgrel=1
pkgdesc="Let's help Certbot client"
arch=('any')
license=('Apache')
url="https://github.com/certbot/${_reponame}"
depends=('python-setuptools' 'python-mock')
makedepends=('git')
provides=("letshelp-certbot=${pkgver}" "letshelp-letsencrypt=${pkgver}")
conflicts=("letshelp-certbot" "letshelp-letsencrypt")
source=("${_reponame}"::"git+https://github.com/certbot/${_reponame}")
sha512sums=('SKIP')

pkgver() {
	cd "${srcdir}/${_reponame}"
	( set -o pipefail
	git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' \
	|| printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

build() {
	cd "${srcdir}/${_reponame}/letshelp-certbot"
	python setup.py clean
	rm -rf build dist
	python setup.py build
}

package() {
	cd "${srcdir}/${_reponame}/letshelp-certbot"
	python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}