blob: 909f7e7ede93dfd3e3e36a5725e110395be4d247 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: HurricanePootis <hurricanepootis@protonmail.com>
# Contributor: Andrew Sun <adsun701 at gmail dot com>
# Contributor: orumin <dev at orum dot in>
_basename=check
pkgname="lib32-$_basename"
pkgver=0.15.2
pkgrel=2
pkgdesc="A unit testing framework for C (32-bit)"
arch=('x86_64')
url="https://libcheck.github.io/check/"
license=('LGPL-2.1-or-later')
depends=('lib32-glibc' "${_basename}" 'lib32-gcc-libs')
makedepends=('git' 'gcc-multilib' 'lib32-gcc-libs')
_commit=11970a7e112dfe243a2e68773f014687df2900e8 # tags/0.15.2
source=("git+https://github.com/libcheck/check#commit=$_commit")
sha512sums=('24d2f93cf92f04c1c3bbd4a60c5f0ad355808f5c0535eb5668f5fe857bce0069690a6c12f37f04ca22f3ba7a4d148bc02195d03f59c24b1a50f54d8bbe3b2cd7')
pkgver() {
cd $_basename
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $_basename
autoreconf -fvi
}
build() {
cd $_basename
export CFLAGS+=' -m32'
export CXXFLAGS+=' -m32'
export LDFLAGS+=' -m32'
export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
./configure --prefix=/usr --disable-static \
--libdir=/usr/lib32
make
}
package() {
cd $_basename
make DESTDIR="$pkgdir" install
rm -rf ${pkgdir}/usr/{bin,share,include}
}
|