summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c72fc199113ad09a9bdc8f18889b828a8cb11119 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Michał Wojdyła < micwoj9292 at gmail dot com >
# Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
# Contributor: Zebulon <zeb@zebulon.org.uk>

pkgname=lib32-libxxf86dga
pkgver=1.1.6
pkgrel=1
pkgdesc="X11 Direct Graphics Access extension library (32 bit)"
arch=('x86_64')
url="http://xorg.freedesktop.org/"
license=('custom')
depends=('lib32-libxext' "${pkgname#*-}")
makedepends=('xorg-util-macros' 'lib32-gcc-libs')
source=("http://xorg.freedesktop.org/releases/individual/lib/libXxf86dga-$pkgver.tar.gz")
sha256sums=('87c7482b1e29b4eeb415815641c4f69c00545a8138e1b73ff1f361f7d9c22ac4')

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  cd libXxf86dga-$pkgver
  ./configure --prefix=/usr --libdir=/usr/lib32 --disable-static
  make
}

package() {
  make -C libXxf86dga-$pkgver DESTDIR="${pkgdir}" install

  # remove things already in libxxf86dga package
  rm -rf "$pkgdir"/usr/{bin,include,share}
  # link to license
  install -d "$pkgdir"/usr/share/licenses
  ln -s ${pkgname#*-} "$pkgdir/usr/share/licenses/$pkgname"
}