PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87

# Maintainer: Markus Kitsinger (SwooshyCueb) <root@swooshalicio.us>
# Contributor: Melvin Vermeeren <mail@mel.vin>
# Contributor: oi_wtf <brainpower at mailbox dot org>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>

pkgname=lib32-sdl-nokbgrab
pkgver=1.2.15
pkgrel=1
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (with noXGrabKeyboard patch) (32-bit)"
arch=('x86_64')
url="https://libsdl.org"
license=('LGPL')
depends=('lib32-libxext' 'lib32-libxrender' 'lib32-libx11' 'sdl-nokbgrab')
makedepends=('lib32-alsa-lib' 'lib32-mesa' 'lib32-libpulse' 'lib32-glu' 'gcc-multilib')
optdepends=('lib32-alsa-lib: ALSA audio driver'
            'lib32-libpulse: PulseAudio audio driver')
conflicts=('lib32-sdl'
           'lib32-sdl-openglhq'
           'lib32-sdl-openglhq-nokbgrab'
           'lib32-sdl-nobackingstore')
provides=("lib32-sdl=${pkgver}")
replaces=("lib32-sdl-nokeyboardgrab")
options=('staticlibs')
source=(https://libsdl.org/release/SDL-${pkgver}.tar.gz
        SDL-1.2.10-GrabNotViewable.patch
        SDL-1.2.15-SDL_EnableUNICODE_drops_keyboard_events.patch
        SDL-1.2.15-const_XData32.patch
        SDL-1.2.15-ignore_insane_joystick_axis.patch
        SDL-1.2.15-no-default-backing-store.patch
        SDL-1.2.15-x11-Bypass-SetGammaRamp-when-changing-gamma.patch
        sdl-1.2.14-fix-mouse-clicking.patch
        sdl-1.2.14-disable-mmx.patch
        libsdl-1.2.15-resizing.patch
        X11_KeyToUnicode.patch)
md5sums=('9d96df8417572a2afb781a7c4c811a85'
         '37ad001a4d2ff924a5fab356b49f8a78'
         '8d5a61a0adf1a302695a30141f402712'
         'd6a1bfa054507f281338626e5f12d74b'
         'e382e5b7449e95969c5ba4084b0aab39'
         '1b0578c76453813eb4eaf0125ce242db'
         '321377e38e2db7f1baf43c392e165dd5'
         '04d8c179f125e04bcd4c9d60e013c2d7'
         'e5c16b7611f62c7cb25f0534eff68852'
         '3dd50347d8856160a9cbd7f80383a1f8'
         'edea272dff4698470877c016d818918d')

prepare() {
  cd SDL-$pkgver
  patch -Np1 -i "${srcdir}/SDL-1.2.10-GrabNotViewable.patch"
  patch -Np1 -i "${srcdir}/SDL-1.2.15-SDL_EnableUNICODE_drops_keyboard_events.patch"
  patch -Np1 -i "${srcdir}/SDL-1.2.15-const_XData32.patch"
  patch -Np1 -i "${srcdir}/SDL-1.2.15-ignore_insane_joystick_axis.patch"
  patch -Np1 -i "${srcdir}/SDL-1.2.15-no-default-backing-store.patch"

  # https://bugs.freedesktop.org/show_bug.cgi?id=27222
  patch -Np1 -i "${srcdir}/SDL-1.2.15-x11-Bypass-SetGammaRamp-when-changing-gamma.patch"

  patch -Np1 -i "${srcdir}/sdl-1.2.14-fix-mouse-clicking.patch"
  patch -Np1 -i "${srcdir}/sdl-1.2.14-disable-mmx.patch"
  patch -Np1 -i "${srcdir}/libsdl-1.2.15-resizing.patch"
  patch -Np1 -i "${srcdir}/X11_KeyToUnicode.patch"

  sed -i '/XGrabKeyboard/{s_^_//_;n;s_^_//_}' src/video/x11/SDL_x11wm.c
}

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  cd "SDL-${pkgver}"
  ./autogen.sh
  ./configure --prefix=/usr --disable-nasm --enable-alsa \
              --with-x --disable-rpath --disable-static --libdir=/usr/lib32
  make
}

package() {
  cd "SDL-${pkgver}"
  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}/usr/"{include,share}

  mv "${pkgdir}/usr/bin/sdl-config" "${pkgdir}/usr/bin/sdl-config-32"
}