blob: 5438a773dc51da4b53f4b5df69a69ebfeb103bf3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Daniel Bermond <dbermond@archlinux.org>
# Contributor: Thomas Schneider <maxmusterm@gmail.com>
_pkgname=svt-av1
pkgname=lib32-svt-av1
pkgver=2.0.0
pkgrel=1
pkgdesc='Scalable Video Technology AV1 encoder and decoder. (32-bits)'
arch=('x86_64')
url="https://gitlab.com/AOMediaCodec/SVT-AV1"
license=(
'BSD'
'custom: Alliance for Open Media Patent License 1.0'
)
depends=(
"svt-av1=${pkgver}"
'lib32-glibc'
'lib32-gcc-libs'
)
makedepends=(
'cmake'
'git'
'nasm'
'ninja'
)
provides=(
'libSvtAv1Dec.so'
'libSvtAv1Enc.so'
)
_tag=2aeeb4f1a1d495b84bf5c21dbb60ae10e991fada
source=("git+https://gitlab.com/AOMediaCodec/SVT-AV1.git#tag=${_tag}")
b2sums=('SKIP')
pkgver() {
cd SVT-AV1
echo "$(git describe --tags | tr -d v)"
}
prepare() {
sed '/CMAKE_BUILD_TYPE Release/d' -i SVT-AV1/CMakeLists.txt
}
build() {
export CC='gcc -m32'
export CXX='g++ -m32'
export PKG_CONFIG='/usr/bin/i686-pc-linux-gnu-pkg-config'
export LDFLAGS="$LDFLAGS -Wl,-z,noexecstack"
cmake -S SVT-AV1 -B build -G Ninja \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=/usr/lib32 \
-DBUILD_SHARED_LIBS=ON \
-DNATIVE=OFF
ninja -C build
}
package() {
DESTDIR="${pkgdir}" ninja -C build install
rm -fr "${pkgdir}/usr/include"
(
cd "${pkgdir}/usr/bin"
mv SvtAv1DecApp SvtAv1DecApp-32
mv SvtAv1EncApp SvtAv1EncApp-32
)
install -Dm 644 SVT-AV1/{LICENSE,PATENTS}.md -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
|