blob: 822146a3d2ae879e7691434d8f60de0e6edd9477 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Maintainer: Gennadiy Mykhailiuta <gmykhailiuta@gmail.com>
# Contributor: Sourav Das <souravdas142@gmail.com>
# Contributor: fordprefect <fordprefect@dukun.de>
pkgname=libcamera-git
_pkgname=libcamera
pkgver=r3989.e0e54965
pkgrel=1
pkgdesc='A complex camera support library for Linux, Android, and ChromeOS'
arch=('x86_64' 'i686' 'aarch64' )
url='http://libcamera.org/'
makedepends=(
"boost"
"gcc"
"git"
"gnutls"
"gst-plugins-base"
"gtest"
"lttng-ust"
"meson"
"openssl"
"python-jinja"
"python-ply"
"python-yaml"
"qt5-base"
"qt5-tools"
"sed"
)
checkdepends=(
)
optdepends=(
"doxygen"
"graphviz"
"gstreamer"
"libevent"
"libtiff"
"python-sphinx"
"udev"
)
license=('LGPL2.1')
options=('!buildflags')
source=(
'git+https://git.linuxtv.org/libcamera.git/'
)
sha256sums=(
'SKIP'
)
provides=("$_pkgname")
conflicts=("$_pkgname")
pkgver() {
cd "$srcdir/$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/$_pkgname"
arch-meson build \
-D b_lto=false \
-D werror=false \
-D documentation=disabled \
-D tracing=disabled \
-D lc-compliance=auto \
-D qcam=auto \
-D pycamera=disabled
meson compile -C build
}
# Disabled because it's impoossible to build libcamera-git without webcam
# plugged in: https://aur.archlinux.org/packages/libcamera-git#comment-839459
# Enable once https://github.com/mesonbuild/meson/issues/6999 is resolved
#check() {
# cd "$srcdir/$_pkgname"
# meson test --no-rebuild --print-errorlogs --skip single_stream_test
# #ninja -C build test
#}
package() {
cd "$srcdir/$_pkgname"
DESTDIR="$pkgdir" ninja -C build install
install -d -m 755 "$pkgdir"/usr/share/licenses/"$_pkgname"
install -D -m 644 ./LICENSES/* "$pkgdir"/usr/share/licenses/"$_pkgname"/
rm -rf "$pkgdir"/usr/share/doc/libcamera-0.0.0/html/.doctrees/
}
|