summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e8786045022098797fd94ac13cd1ca731ac1f067 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: Moritz Kiefer <moritz.kiefer at gmail dot com>
# Contributor: SpotlightKid
pkgname=libgig-svn
_pkgname="${pkgname%-svn}"
pkgver=r3751
pkgrel=1
pkgdesc="Gigasampler file access library"
arch=("i686" "x86_64")
url="http://www.linuxsampler.org/"
license=("GPL")
depends=("libsndfile"
         "util-linux")
makedepends=("subversion")
optdepends=()
provides=("libgig" "libgig.so")
conflicts=("libgig")
source=("$pkgname"::"svn+https://svn.linuxsampler.org/svn/$_pkgname/trunk")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$pkgname"
  local ver="$(svnversion)"
  printf "r%s" "${ver//[[:alpha:]]}"
}

build() {
  cd "$srcdir/$pkgname"
  make -f Makefile.svn
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname"
  make DESTDIR=$pkgdir install

  # add libgig library path to ld.so.conf.d
  install -m0755 -d "$pkgdir/etc/ld.so.conf.d"
  echo "/usr/lib/$_pkgname" > "$pkgdir/etc/ld.so.conf.d/$_pkgname.conf"
}