PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: Lehel Gyuro <lehel@freemail.hu>

pkgname=libindi-orion-ssg3
pkgver=2.2.3.1
pkgrel=1
pkgdesc="INDI driver for products manufactured by indi-orion-ssg3"
url="http://www.indilib.org/index.php?title=Main_Page"
license=(LGPL-2.1-or-later)
arch=(i686 x86_64 aarch64)
depends=(libindi=${pkgver})
makedepends=(cmake)
source=("https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz")
sha256sums=("bb2b25b09f57be7c1aaad6226802b9f0083b415b93046c7fcbde55237410134a")

prepare() {
  mkdir -p build
  cd indi-3rdparty-${pkgver}
  sed -i -e 's@"/lib@"/usr/lib@' indi-orion-ssg3/CMakeLists.txt
}

build() {
  cd build
  cmake -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DFIRMWARE_INSTALL_DIR=/usr \
    ../indi-3rdparty-${pkgver}/indi-orion-ssg3/
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}