PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# $Id$
# Maintainer: Yue Liu <yue.liu@mail.com>

pkgname=libmathview-git
_gitname=libmathview
pkgver=r1278.a007fd2
pkgrel=1
pkgdesc="A library for rendering MathML documents"
arch=('i686' 'x86_64')
url="https://github.com/khaledhosny/libmathview"
license=('LGPL3')
conflicts=('libmathview')
provides=('libmathview')
makedepends=('git' 'autoconf' 'automake' 'libtool' 'pkg-config' 'python2-lxml')
depends=('harfbuzz' 'libxml2' 'cairo' 'qt5-base' 'gtk2')
source=("git://github.com/khaledhosny/libmathview.git#branch=master")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/$_gitname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/$_gitname"
  ./autogen.sh
}

build() {
  cd "$srcdir/$_gitname"
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --disable-static \
    --enable-cairo=yes \
    --enable-qt=yes \
    --enable-gtk=yes \
    --enable-libxml2=yes \
    --enable-custom-reader=no \
    --enable-libxml2-reader=no

  make
}

package() {
  cd "$srcdir/$_gitname"
  make DESTDIR=${pkgdir}/ install
}