summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5e4de63d5cdade302f57b6afc1aebd45962669ed (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgname=libmobi
pkgver=0.11
pkgrel=1
pkgdesc='Library for handling Kindle formats of ebook documents'
arch=('x86_64')
url='https://github.com/bfabiszewski/libmobi'
license=('LGPL3')
depends=('libxml2' 'zlib')
makedepends=('git')
_commit='864e3a86f2565b650f203ec6b1fddc4fb16df925'
source=("$pkgname::git+$url.git#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd "$pkgname"

  git describe --tags | sed 's/^v//'
}

prepare() {
  cd "$pkgname"

  ./autogen.sh
}

build() {
  cd "$pkgname"

  ./configure \
    --prefix=/usr \
    --disable-static \
    --with-libxml2 \
    --with-zlib

  make
}

check() {
  cd "$pkgname"

  make test
}

package() {
  cd "$pkgname"

  make DESTDIR="$pkgdir" install
}