blob: af52c6d834adcbae02fb261cce2718d4bf0bcd78 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Étienne Deparis <etienne@depar.is>
pkgname=libnitrokey-git
_gitname=libnitrokey
pkgver=3.4.1r781.ef171df
pkgrel=1
pkgdesc="Communicate with Nitrokey stick devices in a clean and easy manner"
arch=('i686' 'x86_64')
url="https://www.nitrokey.com"
license=('LGPL3')
depends=(hidapi)
makedepends=('cmake' 'qt5-tools')
provides=('libnitrokey')
conflicts=('libnitrokey')
source=("${_gitname}::git+https://github.com/Nitrokey/${_gitname}.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/${_gitname}/"
curver=$(sed -n 's/^project(libnitrokey LANGUAGES C CXX VERSION \(.*\))$/\1/p' CMakeLists.txt)
printf "%sr%s.%s" "$curver" "$(git rev-list --count HEAD)" \
"$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/${_gitname}/"
mkdir -p build
}
build() {
cd "$srcdir/${_gitname}/build"
cmake .. \
-DBUILD_SHARED_LIBS=ON \
-DCOMPILE_TESTS=OFF \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib
make
}
package() {
cd "$srcdir/${_gitname}/build"
make DESTDIR="$pkgdir" install
cd ..
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${_gitname}/LICENSE"
}
|