blob: fafeb07c290edb8f542b9a499e3025e6c248b0af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Maintainer: Pellegrino Prevete (tallero) <pellegrinoprevete@gmail.com>
_pkg="peas"
_pkgname="lib${_pkg}"
pkgbase="${_pkgname}-git"
pkgname=(
"${_pkgname}2-git"
"${_pkgname}2-docs-git"
)
pkgver=1.99.0+1+g338cf0e
pkgrel=1
pkgdesc="A GObject plugins library"
url="https://wiki.gnome.org/Projects/Lib${_pkg}"
arch=(
x86_64
i686
pentium4
aarch64
armv7h
)
license=(LGPL)
depends=(
gobject-introspection-runtime
gtk3
)
makedepends=(
gi-docgen
git
glade
gobject-introspection
lua51-lgi
meson
python-gobject
vala
)
checkdepends=(xorg-server-xvfb)
optdepends=(
'python-gobject: Python loader')
source=("git+https://gitlab.gnome.org/GNOME/${_pkgname}.git")
sha512sums=('SKIP')
pkgver() {
cd "${_pkgname}"
git describe --tags | sed "s/^${_pkgname}-//;s/-/+/g"
}
build() {
local meson_options=(
-D gtk_doc=true
-D vapi=true
)
arch-meson "${_pkgname}" build "${meson_options[@]}"
meson compile -C build
}
check() {
xvfb-run -s '-nolisten local' \
meson test -C build --print-errorlogs
}
package_libpeas2-git() {
provides=(
"${_pkgname}2=${pkgver}"
"${_pkgname}2"{,-gtk}"-1.0.so")
conflicts=("${_pkgname}2")
meson install -C build --destdir "${pkgdir}"
mkdir -p doc/usr/share
mv {"$pkgdir",doc}/usr/share/doc
}
package_libpeas2-docs-git() {
pkgdesc+=" (documentation)"
depends=()
provides=(
"${_pkgname}2-docs=${pkgver}")
conflicts=("${_pkgname}2-docs")
mv doc/* "$pkgdir"
}
# vim:set sw=2 sts=-1 et:
|