blob: 013395efef93c70463c1e4c61ab0e961deedd2d5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Maintainer: Ryan Petris (ryan@petris.net)
pkgbase=libpod
pkgname=(
"libpod"
"libpod-docker"
)
pkgver=1.0.0
pkgrel=1
pkgdesc="A library used to create container pods."
arch=("x86_64")
url="https://github.com/containers/libpod"
license=("Apache")
makedepends=(
"cni-plugins"
"cri-o"
"device-mapper"
"go"
"go-md2man"
"iptables"
"libseccomp"
"ostree"
"runc"
)
source=("https://github.com/containers/libpod/archive/v${pkgver}.tar.gz")
sha256sums=('f7a462563dd587208eff3c3c0689bc4d01071a8f7933bec2a13126be123f63a8')
prepare() {
export GOPATH="${srcdir}/go"
mkdir -p "${GOPATH}/src/github.com/containers"
sed -i "s/-ldflags '\$(LDFLAGS)'/-gccgoflags '\$(LDFLAGS)'/g" "${pkgbase}-${pkgver}/Makefile"
sed -i "s/-ldflags '\$(LDFLAGS_PODMAN)'/-gccgoflags '\$(LDFLAGS)' -ldflags '\$(LDFLAGS_PODMAN)'/g" "${pkgbase}-${pkgver}/Makefile"
sed -i "s/LDFLAGS_PODMAN ?= \$(LDFLAGS)/LDFLAGS_PODMAN ?=/g" "${pkgbase}-${pkgver}/Makefile"
mv "${pkgbase}-${pkgver}" "${GOPATH}/src/github.com/containers/${pkgbase}"
}
build() {
export GOPATH="${srcdir}/go"
cd "${GOPATH}/src/github.com/containers/${pkgbase}"
sed -i 's/$(GO) build -i/$(GO) build/' Makefile
make install.tools
make all
}
package_libpod() {
depends+=(
"cri-o"
"device-mapper"
"iptables"
"libseccomp"
"runc"
"ostree"
"skopeo"
)
optdepends+=(
"libpod-docker: docker cli"
)
provides+=(
"podman"
# 2018-12-28: keep this for a few releases for packages that depend on it
"libpod-networking"
)
conflicts+=(
"podman"
"libpod-networking"
)
export GOPATH="${srcdir}/go"
cd "${GOPATH}/src/github.com/containers/${pkgbase}"
make install.bin install.cni install.completions install.config install.man install.systemd DESTDIR="${pkgdir}" PREFIX="${pkgdir}/usr"
# seccomp.json is provided by cri-o
rm "${pkgdir}/etc/crio/seccomp.json"
find "${pkgdir}" -type d -empty -delete
}
package_libpod-docker() {
pkgdesc="Use podman as a Docker CLI replacement."
depends+=(
"libpod"
)
conflicts+=(
"docker"
)
provides+=(
"docker"
)
export GOPATH="${srcdir}/go"
cd "${GOPATH}/src/github.com/containers/${pkgbase}"
make install.docker DESTDIR="${pkgdir}" PREFIX="${pkgdir}/usr"
}
|