blob: 4573facd1cc04702b8a1ceccf0f39bf808e36607 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
# Contributor: Jerome Leclanche <jerome@leclan.ch>
_pkgname=libqt6xdg
pkgname=$_pkgname-git
pkgver=3.10.0.6.ga36b76d
pkgrel=1
pkgdesc="Library providing freedesktop.org specs implementations for Qt."
arch=("i686" "x86_64")
url="https://lxqt.org"
license=("LGPL2.1")
depends=("qt6-base" "qt6-svg")
makedepends=("git" "cmake" "qt6-tools" "lxqt-build-tools-qt6-git")
checkdepends=("xorg-server-xvfb")
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("$_pkgname"::"git+https://github.com/lxqt/libqtxdg.git#branch=wip_qt6")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --always | sed "s/-/./g"
}
build() {
mkdir -p build
cd build
cmake "$srcdir/$_pkgname" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DQTXDG_INSTALL_DEFAPPS_CONFIG=OFF \
-DBUILD_TESTS=ON
make
}
check() {
cd build
xvfb-run make test
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|