PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Maintainer: Cody P Schafer <aur@codyps.com>
pkgname=librevault-git
pkgver=0.1.19.r44.de5f35d
pkgrel=1
pkgdesc="File synchronization designed with privacy in mind"
arch=(x86_64 i686)
url="https://librevault.com/"
license=('GPL')
groups=()
makedepends=('git' 'cmake' 'boost' 'qt5-tools')
depends=('qt5-websockets' 'qt5-svg' 'protobuf' 'boost-libs' 'crypto++')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
replaces=()
backup=()
options=()
install=
source=(
	'librevault::git+https://github.com/Librevault/librevault.git'
	'common::git+https://github.com/Librevault/librevault-common.git'
	'dir_monitor::git+https://github.com/Librevault/dir_monitor.git'
	'spdlog::git+https://github.com/Librevault/spdlog.git'
	'docopt::git+https://github.com/Librevault/docopt.cpp.git'
	'rabin::git+https://github.com/Librevault/rabin.git'
	'libnatpmp::git+https://github.com/Librevault/libnatpmp.git'
	'websocketpp::git+https://github.com/Librevault/websocketpp'
	'dht::git+https://github.com/Librevault/dht.git'
	'miniupnp::git+https://github.com/Librevault/miniupnp.git'
)
noextract=()
md5sums=('SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP'
         'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP')

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	printf "%s" "$(git describe --long | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g')"
}

prepare() {
	mkdir -p build
	cd "$srcdir/${pkgname%-git}"
	git submodule init
	git config submodule.common.url "$srcdir/common"
	git config submodule.contrib/dir_monitor.url "$srcdir/dir_monitor"
	git config submodule.contrib/spdlog.url "$srcdir/spdlog"
	git config submodule.contrib/docopt.url "$srcdir/docopt"
	git config submodule.contrib/rabin.url "$srcdir/rabin"
	git config submodule.contrib/libnatpmp.url "$srcdir/libnatpmp"
	git config submodule.contrib/websocketpp.url "$srcdir/websocketpp"
	git config submodule.contrib/dht.url "$srcdir/dht"
	git config submodule.contrib/miniupnp.url "$srcdir/miniupnp"
	git submodule update
}

build() {
	cd build
	cmake "$srcdir/${pkgname%-git}" \
		-DCMAKE_BUILD_TYPE=Release \
		-DBUILD_TESTING=OFF \
		-DCMAKE_INSTALL_PREFIX=/usr
	make
}

package() {
	cd build
	make DESTDIR="$pkgdir" install
}