blob: 27d497a76361031a5bfced9d0038178f8a0fa03d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Maintainer: David Kantun <dkantun@gmail.com>
pkgname=libria
pkgver=1.8.4
pkgrel=1
pkgdesc="Application for professional book creation and typesetting — book editor and layout tool with real-time preview, EPUB/DOCX/PDF export, and spell checking"
arch=('x86_64')
url="https://github.com/Gargadon/libria"
license=('MIT')
depends=('electron>=32' 'ghostscript')
makedepends=('bun' 'python')
provides=("${pkgname}")
source=("${url}/archive/v${pkgver}.tar.gz")
sha256sums=('4ff3ac1257359664f8e4c161494743bfb5a04ba81842352a89e0183f62e62f65')
prepare() {
cd "${srcdir}/libria-${pkgver}"
bun install
}
build() {
cd "${srcdir}/libria-${pkgver}"
bun run build
}
package() {
cd "${srcdir}/libria-${pkgver}"
# Aplicación
local _dest="${pkgdir}/opt/libria"
install -dm755 "${_dest}/dist/libria"
cp -r dist/libria/browser/. "${_dest}/dist/libria/browser/"
cp main.js preload.js package.json "${_dest}/"
cp -r build/licenses "${_dest}/licenses"
install -Dm644 build/icon.png "${_dest}/build/icon.png"
# Script de lanzamiento
install -dm755 "${pkgdir}/usr/bin"
cat > "${pkgdir}/usr/bin/libria" << 'SCRIPT'
#!/bin/bash
export GDK_BACKEND=x11
export ELECTRON_OZONE_PLATFORM_HINT=x11
exec /usr/bin/electron --ozone-platform=x11 /opt/libria/main.js "$@"
SCRIPT
chmod 755 "${pkgdir}/usr/bin/libria"
# Desktop entry
install -dm755 "${pkgdir}/usr/share/applications"
cat > "${pkgdir}/usr/share/applications/libria.desktop" << 'DESKTOP'
[Desktop Entry]
Name=Libria
Comment=Professional book editor and typesetter
Exec=/usr/bin/libria %F
Icon=libria
Terminal=false
Type=Application
MimeType=application/x-libria;
Categories=Office;WordProcessor;Development;
StartupWMClass=Libria
DESKTOP
# Icono
install -Dm644 build/icon.png "${pkgdir}/usr/share/icons/hicolor/256x256/apps/libria.png"
# Asociación de archivos .libria
install -dm755 "${pkgdir}/usr/share/mime/packages"
cat > "${pkgdir}/usr/share/mime/packages/libria.xml" << 'MIME'
<?xml version="1.0" encoding="UTF-8"?>
<mime-info xmlns="http://www.freedesktop.org/standards/shared-mime-info">
<mime-type type="application/x-libria">
<comment>Libria Document</comment>
<glob pattern="*.libria"/>
<icon name="libria"/>
</mime-type>
</mime-info>
MIME
# Licencias
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/libria/LICENSE"
}
|