blob: dd0334b76a9fbe1257c25109a2c21bb4dbf99602 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=libtorrent-rasterbar-2_0-git
pkgver=2.0.11.r120.g47b84956d
pkgrel=1
pkgdesc="A feature complete C++ bittorrent library (git branch RC_2_0)"
arch=('i686' 'x86_64')
url="https://www.libtorrent.org/"
license=('BSD-3-Clause')
depends=('glibc' 'libgcc' 'libstdc++' 'boost-libs' 'openssl')
makedepends=('git' 'boost' 'cmake' 'python' 'python-setuptools')
provides=("libtorrent-rasterbar=$pkgver")
conflicts=('libtorrent-rasterbar')
source=('git+https://github.com/arvidn/libtorrent.git#branch=RC_2_0')
sha256sums=('SKIP')
prepare() {
cd "libtorrent"
git submodule update --init --recursive
}
pkgver() {
cd "libtorrent"
_tag=$(git tag -l --sort -v:refname | grep -E '^v2\.0\.[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count "$_tag"..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "libtorrent"
cmake \
-B "_build" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR="lib" \
-Dpython-bindings=ON \
-Dpython-egg-info=ON \
-Dboost-python-module-name="python" \
./
cmake --build "_build"
}
package() {
cd "libtorrent"
DESTDIR="$pkgdir" cmake --install "_build"
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/libtorrent-rasterbar"
}
|