blob: c183451e8cb06e80c432027671fefb1a366a0f48 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: twa022 <twa022 at gmail dot com>
_pkgname=libxfce4windowing
pkgname=${_pkgname}-devel
pkgver=4.19.10
pkgrel=1
pkgdesc="Windowing concept abstraction library for X11 and Wayland (Development version)"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url="https://docs.xfce.org/xfce/libxfce4windowing/start"
license=('LGPL2.1')
groups=('xfce4-devel')
depends=('libwnck3' 'wayland' 'libdisplay-info')
makedepends=('meson' 'xfce4-dev-tools>=4.19.2' 'gtk-doc' 'gobject-introspection' 'wayland-protocols' 'wlr-protocols')
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
source=("https://archive.xfce.org/src/xfce/${_pkgname}/${pkgver%.*}/${_pkgname}-${pkgver}.tar.bz2")
sha256sums=('356a08b92a04b887fefa0675cba705dc2e7d337d37f0ee6f28a7e9a1491e62d5')
build() {
local meson_options=(
-D gtk-doc=true
-D x11=enabled
-D wayland=enabled
)
arch-meson "${_pkgname}-${pkgver}" build "${meson_options[@]}"
meson compile -C build
}
package() {
meson install -C build --destdir "$pkgdir"
}
|