blob: 368d3677eba6e4114bb80a48110b14bebfb82dc9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Helpful url: https://services.lidarr.audio/v1/update/nightly?version=0.0.0.0&os=linux&runtime=netcore&arch=x64
pkgname="lidarr-develop"
pkgver=2.2.5.4141
pkgrel=1
pkgdesc="Music download automation for usenet and torrents."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/lidarr/Lidarr"
license=("GPL3")
depends=('sqlite' 'chromaprint')
options=('!strip' 'staticlibs')
optdepends=('sabnzbd: usenet downloader'
'nzbget: usenet downloader'
'transmission-cli: torrent downloader (CLI and daemon)'
'transmission-gtk: torrent downloader (GTK+)'
'transmission-qt: torrent downloader (Qt)'
'deluge: torrent downloader'
'rtorrent: torrent downloader'
'qbittorrent: torrent downloader'
'qbittorrent-nox: torrent downloader (no X)'
'jackett: torrent indexer proxy'
'libgdiplus: provides a gdi+ compatible api')
provides=('lidarr')
conflicts=('lidarr' 'lidarr-nightly')
source_x86_64=("lidarr-${pkgver}-linux-core-x64.tar.gz::https://services.lidarr.audio/v1/update/develop/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=x64")
source_aarch64=("lidarr-${pkgver}-linux-core-arm64.tar.gz::https://services.lidarr.audio/v1/update/develop/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm64")
source_armv7h=("lidarr-${pkgver}-linux-core-arm.tar.gz::https://services.lidarr.audio/v1/update/develop/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm")
source=('lidarr.service'
'lidarr.tmpfiles'
'lidarr.sysusers'
'package_info')
sha512sums=('fdf34b2105bbdd546bd4e9520e8c69ae594b87ea8c2581b8bdb69b54d7c54b6647187aa4dcb09d48d679a6f5b9ebf405ee90103dd8ef5535c4cf6d40e1178f66'
'3800547b7c3d2b6e0a590ebd2db5ed48a6c31249098a4c36876faca36dd81e84ac45f3679d16bfe101be594dc6d5d0cfc91bfc66ed8cba35ec05f22027ab2441'
'ffd466960527256d8de1d9887d90d4da87486eff062950c46cbc4fd4af1ef89e7d5c070ef1e649b23a95fbab15651e289fd5bdc6d34649e4a6ecdf2f6da06622'
'c9bd8707cceed880ecebd974f0c5db0801cfafd714bf939e9c688212e4b092cc9e6452c899ae30d8d5c5acc9a4e41c9fa0f1e5c1daef7cdb0bd5d66c6be0eb4a')
sha512sums_x86_64=('7a86888bb17fd48beb85e32406dda360aa28ebd2ba976cda38537ab77b0ce88d1e29c5548d97a37119c3f629313d2fc1aa44f7514868b3998427ccd6b262d282')
sha512sums_aarch64=('8569d7ec5d628b44eb2abb044a92916fa94848964be4dbd26f740b463bd0b4fa6b34a16ed19fe74e7df7a0754e3ba1db7d05aeb6578ff5179a016c0f29cfb3ea')
sha512sums_armv7h=('a268edffcbf5711ebaf69eba14291f31bd87170a7a096c978115a4e85b02276f447efeb0c330b5b34db1a40cde2f7ac9db6b8b5b30e4c0fb2ebf92d6282d4a3e')
package() {
# Update environment isn't needed.
rm -rf "${srcdir}/Lidarr/Lidarr.Update"
# The fpcalc binary comes from chromaprint.
rm -rf "${srcdir}/Lidarr/fpcalc"
install -d -m 755 "${pkgdir}/usr/lib/lidarr/bin"
cp -dpr --no-preserve=ownership "${srcdir}/Lidarr/"* "${pkgdir}/usr/lib/lidarr/bin"
chmod -R a=,a+rX,u+w "${pkgdir}/usr/lib/lidarr/bin"
chmod +x "${pkgdir}/usr/lib/lidarr/bin/Lidarr"
# Disable built in updater.
install -D -m 644 "${srcdir}/package_info" "${pkgdir}/usr/lib/lidarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/lidarr/package_info"
install -D -m 644 "${srcdir}/lidarr.service" "${pkgdir}/usr/lib/systemd/system/lidarr.service"
install -D -m 644 "${srcdir}/lidarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/lidarr.conf"
install -D -m 644 "${srcdir}/lidarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/lidarr.conf"
}
|