blob: ed195ca7ae53d28c098ed267228eccbc50f53191 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: txtsd <aur.archlinux@ihavea.quest>
# Contributor: Donald Webster <fryfrog@gmail.com>
# Helpful URL: https://services.lidarr.audio/v1/update/nightly?version=0.0.0.0&os=linux&runtime=netcore&arch=x64
pkgname=lidarr-nightly-bin
pkgver=2.7.0.4406
pkgrel=1
pkgdesc='Music collection manager for newsgroup and torrent users (nightly builds)'
arch=('x86_64' 'aarch64' 'armv7h')
url='https://lidarr.audio'
license=('GPL-3.0-or-later')
groups=('servarr-nightly-bin')
depends=(
'gcc-libs'
'glibc'
'zlib'
'sqlite'
)
optdepends=(
'postgresql: postgresql database'
'sabnzbd: usenet downloader'
'nzbget: usenet downloader'
'qbittorrent: torrent downloader'
'deluge: torrent downloader'
'rtorrent: torrent downloader'
'transmission-cli: torrent downloader (CLI and daemon)'
'transmission-gtk: torrent downloader (GTK+)'
'transmission-qt: torrent downloader (Qt)'
'jackett: torrent indexer proxy'
'nzbhydra2: torznab and usenet indexer proxy'
'prowlarr: torrent and usenet indexer proxy'
'autobrr: irc, torrent and usenet indexer proxy'
)
provides=(lidarr)
conflicts=(lidarr)
options=('!debug')
source=(
'lidarr.service'
'lidarr.tmpfiles'
'lidarr.sysusers'
'package_info'
)
source_x86_64=("Lidarr.nightly.${pkgver}.linux-core-x64.tar.gz::https://lidarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=x64")
source_aarch64=("Lidarr.nightly.${pkgver}.linux-core-arm64.tar.gz::https://lidarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm64")
source_armv7h=("Lidarr.nightly.${pkgver}.linux-core-arm.tar.gz::https://lidarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm")
sha256sums=('dcbe3d2a3d64a78a4b2b84a3486991a8b90fdd6900d7345004827a168f8b5645'
'abde8989e7ab9dc62b6a501644da5a9253953b6394b890565e00a69cbfd89068'
'19b36aefd2ef93d4a630ceaefe582573ecdaa72ec21bfb48ce3941ead7b967fb'
'90a1960fef0d3833cd3635cedd16af3ee9ae6c7b95babc3021f6031d4e44c200')
sha256sums_x86_64=('8da46d0c79db9e5f351bf2601a1a044d85edf26745a0e9d09d2221e556b8efd6')
sha256sums_aarch64=('5699692028a0c5cb8e79b93ab61c7d9423648e64bf3c9c53513ba2f5a85e5a96')
sha256sums_armv7h=('d4bbe529a16772a79432842011596fc746493ecbc24a5d9c2f771b2284d7d427')
package() {
install -dm755 "${pkgdir}/usr/lib/lidarr/bin"
# License
install -Dm644 "${srcdir}/Lidarr/LICENSE.md" "${pkgdir}/usr/share/licenses/${pkgname}"
rm "${srcdir}/Lidarr/LICENSE.md"
# Disable built in updater.
rm -rf "${srcdir}/Lidarr/Lidarr.Update"
install -Dm644 "${srcdir}/package_info" "${pkgdir}/usr/lib/lidarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/lidarr/package_info"
cp -dpr --no-preserve=ownership "${srcdir}/Lidarr/"* "${pkgdir}/usr/lib/lidarr/bin"
install -Dm644 "${srcdir}/lidarr.service" "${pkgdir}/usr/lib/systemd/system/lidarr.service"
install -Dm644 "${srcdir}/lidarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/lidarr.conf"
install -Dm644 "${srcdir}/lidarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/lidarr.conf"
}
|