summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ddcbebc2fd2114719b11fed18f0ccd889e05d139 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: sh4nks <sh4nks7@gmail.com

pkgname=lightdm-pantheon-greeter-git
pkgver=3.3.1.r104.13f8dc9
pkgrel=1
pkgdesc='Pantheon greeter for LightDM'
arch=(x86_64)
url=https://github.com/elementary/greeter
license=(GPL)
groups=(pantheon-unstable)
depends=(
  accountsservice
  cairo
  gdk-pixbuf2
  glib2
  gtk3
  libmutter2
  libgee
  libgl
  libgranite.so
  libx11
  lightdm
)
makedepends=(
  meson
  git
  granite-git
  libglvnd
  libxfixes
  vala
)
provides=(lightdm-pantheon-greeter)
conflicts=(lightdm-pantheon-greeter)
install=lightdm-pantheon-greeter.install
source=(lightdm-pantheon-greeter::git+https://github.com/elementary/greeter.git)
sha256sums=(SKIP)

pkgver() {
  cd lightdm-pantheon-greeter

  git describe --tags | sed 's/-/.r/; s/-g/./'
}

build() {
  arch-meson lightdm-pantheon-greeter build \
    -D ubuntu-patched-gsd=false
  ninja -C build
}

package() {
  DESTDIR="${pkgdir}" meson install -C build
}

# vim: ts=2 sw=2 et: