blob: b4f829414a05eb1517a42a01767b99bca630b1a5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=liketaskmanager-git
pkgver=2.4.r4.gf491ab2
pkgrel=1
pkgdesc="Tool that mimics the permformance monitoring of Windows Task Manager"
arch=('x86_64')
url="https://github.com/rejuce/LikeTaskManager"
license=('GPL-3.0-or-later')
depends=(
'nethogs'
'qt6-base'
'qwt-qt6'
)
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+https://github.com/rejuce/LikeTaskManager.git"
"${pkgname%-git}.desktop"
'includepath.patch')
sha256sums=('SKIP'
'c1655277c90a158ceed2fe461297ccd148f7746c4f19320de4c375a4e49ada0b'
'60d39abcb40047801cabcbde144964fb0d28a0b1635b6cd41409af159656367f')
pkgver() {
cd LikeTaskManager
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd LikeTaskManager
# Remove precompiled binary
rm -fv LikeTaskManager
# Correct INCLUDEPATH
patch -Np1 -i ../includepath.patch
}
build() {
cd LikeTaskManager
qmake6
make
}
package() {
cd LikeTaskManager
install -Dm755 LikeTaskManager -t "$pkgdir/usr/bin/"
install -Dm644 "$srcdir/${pkgname%-git}.desktop" -t "$pkgdir/usr/share/applications"
}
|