PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# Maintainer: Reto <reto@sligthlybroken.com>
# Contributor: Cravix < dr dot neemous at gmail dot com >

pkgname=limnoria
pkgver=2024.12.20
pkgrel=1
pkgdesc="A robust, full-featured and user/programmer-friendly Python IRC bot"
arch=('any')
url="https://github.com/ProgVal/Limnoria"
license=('BSD')
depends=('python')
makedepends=(python-build python-installer python-wheel python-setuptools)
optdepends=(
'python-chardet: to detect encoding of incoming IRC lines, if they are not in UTF-8'
'python-gnupg: for authenticated based on GPG tokens'
'python-pysocks: for SOCKS proxy (typically used to connect to IRC via Tor)'
'python-cryptography: required to load the Fediverse plugin (used to implement HTTP signatures)'
'python-feedparser: required to load the RSS plugin'
'python-dateutil: enable fancy time string parsing in the Time plugin'
)
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz")
sha256sums=('7bc62f076f6d820b2c5fc68c452a0bbe9aec48159e29529f843ad265e036ac24')

build() {
    cd "$srcdir/$pkgname-$pkgver" || exit 1
    python -m build --wheel --no-isolation
}

package() {
    cd "$srcdir/$pkgname-$pkgver" || exit 1
    python -m installer --destdir="$pkgdir" dist/*.whl
}