blob: e54af0ccf10dd1985437f4798028960864645853 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# Maintainer: Cyano Hao <c@cyano.cn>
_pkgbase=linux-elbin # for mkinitcpio hook
pkgname=linux-el-bin
_basever=4.18.0
_rhver=348.7.1
_rocky_ver="8.5"
pkgver=$_rhver.kabi.$_basever
epoch=8
pkgrel=1
pkgdesc="The Enterprise Linux kernel, modules, headers and documentation (Rocky Linux binary)"
url="https://git.rockylinux.org/staging/rpms/kernel"
arch=(x86_64)
license=(GPL2)
depends=(coreutils kmod initramfs)
optdepends=(
'crda: to set the correct wireless channels of your country'
'linux-firmware: firmware images needed for some devices'
'pahole: utility for building kernel modules'
)
makedepends=(xz cpio)
options=('!strip')
backup=("etc/mkinitcpio.d/$_pkgbase.preset")
install=linux-elbin.install
# corresponding packages (rhel -> archlinux)
# kernel -> N/A (meta package)
# ✓ kernel-core -> linux
# ✓ kernel-modules -> linux
# kernel-modules-extra -> N/A (obsolete)
# ✓ kernel-devel -> linux-headers
# ✓ kernel-doc -> linux-docs
# kernel-headers -> linux-api-headers
# kernel-tools -> N/A (misc userland utils)
_rocky_mirror="https://download.rockylinux.org/pub/rocky"
_rpmver=$_basever-$_rhver.el${_rocky_ver/\./_}
source=(
"$_rocky_mirror/$_rocky_ver/BaseOS/x86_64/os/Packages/k/kernel-core-$_rpmver.x86_64.rpm"
"$_rocky_mirror/$_rocky_ver/BaseOS/x86_64/os/Packages/k/kernel-modules-$_rpmver.x86_64.rpm"
"$_rocky_mirror/$_rocky_ver/BaseOS/x86_64/os/Packages/k/kernel-devel-$_rpmver.x86_64.rpm"
"$_rocky_mirror/$_rocky_ver/BaseOS/x86_64/os/Packages/k/kernel-doc-$_rpmver.noarch.rpm"
"$_pkgbase.preset"
)
noextract=(kernel-doc-$_rpmver.noarch.rpm) # bsdtar cannot extract it
sha256sums=('eca536bff5108eb76988aa572e323de7bb02220a2b007ab11f394c15e091d895'
'00060cfa0c4f66c527f592bd87d1e914202ecf26cfe0bc31e1a408dcbf6ef976'
'a95d6ab710379905db235afdd406bf3fd44be31c1c3f5a95a0fa9037e89420f5'
'e9fff3a106e20eee79789ebc5fdc5d3bd1ee7b0d54b87341a4798a359746bc6d'
'dcb7f4f352395287152bb6a3469171d9199b1e000bab9f244e17db893cff70d9')
_rpm2cpio() {
# source: `rpm2cpio` from extra/rpmextract
leadsize=96
o=`expr $leadsize + 8`
set `od -j $o -N 8 -t u1 $pkg`
il=`expr 256 \* \( 256 \* \( 256 \* $2 + $3 \) + $4 \) + $5`
dl=`expr 256 \* \( 256 \* \( 256 \* $6 + $7 \) + $8 \) + $9`
# echo "sig il: $il dl: $dl"
sigsize=`expr 8 + 16 \* $il + $dl`
o=`expr $o + $sigsize + \( 8 - \( $sigsize \% 8 \) \) \% 8 + 8`
set `od -j $o -N 8 -t u1 $pkg`
il=`expr 256 \* \( 256 \* \( 256 \* $2 + $3 \) + $4 \) + $5`
dl=`expr 256 \* \( 256 \* \( 256 \* $6 + $7 \) + $8 \) + $9`
# echo "hdr il: $il dl: $dl"
hdrsize=`expr 8 + 16 \* $il + $dl`
o=`expr $o + $hdrsize`
dd if=$pkg ibs=$o skip=1 2>/dev/null
}
prepare() {
echo "Extracting kernel-doc-$_rpmver.noarch.rpm"
pkg=kernel-doc-$_rpmver.noarch.rpm _rpm2cpio | unxz | cpio -idm
}
package() {
cd "$srcdir"
install -Dm644 $_pkgbase.preset "$pkgdir"/etc/mkinitcpio.d/$_pkgbase.preset
# kernel image and modules
install -m755 -d "$pkgdir"/usr/lib/modules/
cp -r lib/modules/$_rpmver.x86_64/ "$pkgdir"/usr/lib/modules/$_rpmver.x86_64
# mkinitcpio hook
echo $_pkgbase >"$pkgdir"/usr/lib/modules/$_rpmver.x86_64/pkgbase
# create modules.* files
depmod -b "$pkgdir"/usr $_rpmver.x86_64
# headers
# dkms hook requires headers in module directory
rm "$pkgdir"/usr/lib/modules/$_rpmver.x86_64/build
cp -r usr/src/kernels/$_rpmver.x86_64/ "$pkgdir"/usr/lib/modules/$_rpmver.x86_64/build
# symlink
install -m755 -d "$pkgdir"/usr/src/
ln -s ../lib/modules/$_rpmver.x86_64/build "$pkgdir"/usr/src/$_pkgbase
# docs
# follow arch linux packaging schema
cp -r usr/share/doc/kernel-doc-$_basever/Documentation "$pkgdir"/usr/lib/modules/$_rpmver.x86_64/build/Documentation
# symlink
install -m755 -d "$pkgdir"/usr/share/doc/
ln -s ../../lib/modules/$_rpmver.x86_64/build/Documentation "$pkgdir"/usr/share/doc/$_pkgbase
}
|