blob: da7cb081992e87f4361864fb1cd931ec700917f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Maintainer: Kirikaze Chiyuki <me@chyk.ink>
# Maintainer: sukanka
_pkgname=linuxqq
_base_pkgver=3.2.13_241112
_update_pkgver=${_base_pkgver}
_md5=08c52833
pkgname=linuxqq-nt-bwrap
pkgver="${_update_pkgver//-/_}"
pkgrel=1
pkgdesc="New Linux QQ based on Electron, with bubblewrap sandbox and some tweaks"
arch=('x86_64' 'aarch64' 'loong64')
url='https://im.qq.com/linuxqq/index.shtml'
license=('custom')
depends=('at-spi2-core' 'alsa-lib' 'desktop-file-utils' 'gtk3' 'gtk-update-icon-cache' 'libnotify' 'nss'
'gnutls' 'bubblewrap' 'xdg-user-dirs' 'flatpak-xdg-utils' 'snapd-xdg-open-git'
'libvips' 'openslide' 'autoconf'
'libunwind'
'iproute2'
)
makedepends=('p7zip')
optdepends=('libappindicator-gtk3: 以显示托盘图标'
'gjs: 提供 GNOME Wayland 下的截图支持'
'slirp4netns: 固定 MAC 地址时需要'
'socat: 固定 MAC 地址时需要')
provides=('qq' 'linuxqq')
conflicts=('linuxqq')
options=('!emptydirs')
install="${pkgname}.install"
source_x86_64=("https://dldir1.qq.com/qqfile/qq/QQNT/Linux/QQ_${_base_pkgver}_amd64_01.deb")
source_aarch64=("https://dldir1.qq.com/qqfile/qq/QQNT/Linux/QQ_${_base_pkgver}_arm64_01.deb")
source_loong64=("https://dldir1.qq.com/qqfile/qq/QQNT/Linux/QQ_${_base_pkgver}_loongarch64_01.deb")
source=('start.sh' 'start_normal.sh' 'start_mac_fix.sh' 'start_inner.sh' 'config.json' 'resolv.conf' 'xdg-open.sh')
sha256sums=('2748a351259d378ab9773000cbf1ea0448de5ae92f28bb9e366fa795e1715739'
'46958947a35bde1cea2a2f2da6e8296fcb6752d84b6c62b2a49f6959d3235912'
'801d778cb2cecca21cc294651ac5c85ad1c8cdd8c805c9d491740dd13bb9c7dc'
'3c78b576aa5d07e4cacde95d1088530503478bb0d43d19371c5da56f675d9861'
'bb2ec0f104da4da7422d9b0f51c71d0ab38ed2a21764a7a643ab42689e098e4b'
'cc002ee0eb2e8702c97d16f4ce628841cd5fe10195875a075432e92248741424'
'f1c778b5a8b23bc77fd8e5e89056fea07309794c9a44ec38134a176cf1f7b675')
sha256sums_x86_64=('c9c18d8a12d871e980dfb3c6a464f98426a2ab99c3e0aba6a92305ed32a4e222')
sha256sums_aarch64=('7805a778c2ba689515b9d41e9a06a76918839c41ad0dc241f73d0e21e8650f8f')
sha256sums_loong64=('f9fcf68cf626ea26b22483fbfd52ceea3554e297d6c054692637aa513a50cd4a')
prepare() {
local base_ver=${_base_pkgver}
local cur_ver=${_update_pkgver:-${base_ver}}
local build_ver=${cur_ver#*-}
sed -i "s|__BASE_VER__|${base_ver}|g;s|__CURRENT_VER__|${cur_ver}|g;s|__BUILD_VER__|${build_ver}|g" config.json start.sh
}
package() {
# 解压程序包
tar -xJ -f "data.tar.xz" -C "${pkgdir}"
chmod 755 "${pkgdir}/opt/QQ/resources/app"
mv "${pkgdir}/opt/QQ/qq" "${pkgdir}/opt/QQ/electron"
# 打包相关处理
mkdir -p "${pkgdir}/opt/QQ/workarounds"
install -Dm755 "xdg-open.sh" "${pkgdir}/opt/QQ/workarounds/xdg-open.sh"
cp "${srcdir}/config.json" "${pkgdir}/opt/QQ/workarounds/config.json"
cp "${srcdir}/resolv.conf" "${pkgdir}/opt/QQ/workarounds/resolv.conf"
# 将 LICENSE 移动到正确位置
mkdir -p "${pkgdir}/usr/share/licenses/${_pkgname}"
ln -s "/opt/QQ/LICENSE.electron.txt" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
ln -s "/opt/QQ/LICENSES.chromium.html" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSES.chromium.html"
# 删除原生库
rm -f "${pkgdir}"/opt/QQ/resources/app/{libssh2.so.1,libunwind*,sharp-lib/libvips-cpp.so.42}
# 对 desktop 文件做处理，使其使用正确的图标，启动 start.sh
cp "${srcdir}/start"*".sh" "${pkgdir}/opt/QQ/"
sed -i "s|/opt/QQ/qq|/opt/QQ/start.sh|" "${pkgdir}/usr/share/applications/qq.desktop"
sed -i "s|Icon=/usr/share/icons/hicolor/512x512/apps/qq.png|Icon=qq|" "${pkgdir}/usr/share/applications/qq.desktop"
# 这样就可以直接输入 qq 命令启动了
mkdir -p "${pkgdir}/usr/bin"
ln -s "/opt/QQ/start.sh" "${pkgdir}/usr/bin/qq"
}
|