blob: 0b454b63b6ce12ee9261a42ada1b5f9646f16923 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Serene-Arc
pkgname=listenbrainz-playlist-uploader-git
pkgver=0.1.0.r1.g32408ff
pkgrel=1
pkgdesc="A tool for uploading playlists to ListenBrainz with feedback"
url="https://github.com/Serene-Arc/listenbrainz-playlist-uploader"
license=("MIT")
arch=("x86_64")
makedepends=(cargo)
source=("$pkgname::git+https://github.com/Serene-Arc/listenbrainz-playlist-uploader.git")
options=("debug" "!strip")
sha256sums=("SKIP")
pkgver() {
cd "$pkgname"
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
export RUSTUP_TOOLCHAIN=stable
cd "$srcdir/$pkgname"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd "$srcdir/$pkgname"
cargo build --frozen --release --all-features
}
check() {
export RUSTUP_TOOLCHAIN=stable
cd "$srcdir/$pkgname"
cargo test --frozen --all-features
}
package() {
cd "$srcdir/$pkgname"
install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/listenbrainz-playlist-uploader"
}
|