blob: 539d86a3d592c02103123cefc57fb3af540d40c9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
# Maintainer: fabse
# Contributor: txtsd <aur.archlinux@ihavea.quest>
# Contributor: envolution
pkgname=llama.cpp-cuda
_pkgname=${pkgname%%-cuda}
pkgver=b9969 # renovate: datasource=github-releases depName=ggml-org/llama.cpp
pkgrel=1
pkgdesc="Port of Facebook's LLaMA model in C/C++ (with NVIDIA CUDA optimizations)"
arch=(x86_64 armv7h aarch64)
url='https://github.com/ggml-org/llama.cpp'
license=('MIT')
depends=(
curl
gcc-libs
glibc
cuda
nvidia-utils
python
)
makedepends=(
cmake
cudnn
git
shaderc
ninja
npm
)
optdepends=(
'nccl: needed for multi-GPU parallelism'
'python-numpy: needed for convert_hf_to_gguf.py'
'python-safetensors: needed for convert_hf_to_gguf.py'
'python-sentencepiece: needed for convert_hf_to_gguf.py'
'python-pytorch: needed for convert_hf_to_gguf.py'
'python-transformers: needed for convert_hf_to_gguf.py'
'python-gguf: needed for convert_hf_to_gguf.py'
)
provides=(${_pkgname})
conflicts=(${_pkgname} libggml ggml)
options=(lto !debug)
backup=("etc/conf.d/llama.cpp")
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/ggml-org/llama.cpp/archive/refs/tags/${pkgver}.tar.gz"
llama.cpp.conf
llama.cpp.service
)
sha256sums=('5e7bff79a963a781c495766613219ff91c1740e8901cc3c8135b72fbac0d970b'
'53fa70cfe40cb8a3ca432590e4f76561df0f129a31b121c9b4b34af0da7c4d87'
'0377d08a07bda056785981d3352ccd2dbc0387c4836f91fb73e6b790d836620d')
prepare() {
ln -sf "${_pkgname}-${pkgver}" llama.cpp
}
build() {
if [[ -z "${NVCC_CCBIN}" ]]; then
source /etc/profile
fi
local _cmake_options=(
-G Ninja
-B build
-S "${_pkgname}"
-DCMAKE_BUILD_TYPE=Release
-DCMAKE_INSTALL_PREFIX='/usr'
-DBUILD_SHARED_LIBS=ON
-DLLAMA_BUILD_TESTS=OFF
-DLLAMA_USE_SYSTEM_GGML=OFF
-DLLAMA_BUILD_UI=ON
-DLLAMA_USE_PREBUILT_UI=OFF
-DGGML_ALL_WARNINGS=OFF
-DGGML_ALL_WARNINGS_3RD_PARTY=OFF
-DGGML_BUILD_EXAMPLES=OFF
-DGGML_BUILD_TESTS=OFF
-DGGML_LTO=ON
-DGGML_RPC=ON
-DGGML_CUDA=ON
-DGGML_CUDA_FA_ALL_QUANTS=ON
-DGGML_CUDNN=ON
-DLLAMA_BUILD_NUMBER="${pkgver#b}"
-Wno-dev
)
if [ -n "$CI" ] && [ "$CI" != 0 ]; then
echo "CI = $CI detected, building universal package"
_cmake_options+=(
-DGGML_BACKEND_DL=ON
-DGGML_CPU_ALL_VARIANTS=ON
-DGGML_NATIVE=OFF
)
else
_cmake_options+=(
-DGGML_NATIVE=ON
)
fi
# Allow user-specified additional flags
if [[ -n "$LLAMA_BUILD_EXTRA_ARGS" ]]; then
echo "Applied custom CMake build args: $LLAMA_BUILD_EXTRA_ARGS"
_cmake_options+=($LLAMA_BUILD_EXTRA_ARGS)
fi
cmake "${_cmake_options[@]}"
cmake --build build -- -j $(nproc)
}
package() {
DESTDIR="${pkgdir}" cmake --install build
install -Dm644 "${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 "llama.cpp.conf" "${pkgdir}/etc/conf.d/llama.cpp"
install -Dm644 "llama.cpp.service" "${pkgdir}/usr/lib/systemd/system/llama.cpp.service"
}
# vim:set ts=2 sw=2 et:
|