blob: 8993147dc3340508e7b580c8f35d74be2a293e21 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: robertfoster
pkgname=local-ai
pkgver=4.2.6 # renovate: datasource=github-tags depName=mudler/LocalAI
pkgrel=1
pkgdesc="Free, Open Source OpenAI alternative. Self-hosted, community-driven and local-first"
arch=('x86_64')
url="https://github.com/mudler/LocalAI"
license=('MIT')
backup=("etc/${pkgname}/${pkgname}.conf")
makedepends=(
'go'
'make'
'unzip'
)
source=("${pkgname}-${pkgver}::git+${url}.git#tag=v${pkgver}"
"${pkgname}.conf"
"${pkgname}.tmpfiles"
"${pkgname}.sysusers"
"${pkgname}.service"
)
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export GOPATH="${srcdir}"
export PATH="${GOPATH}/bin:${PATH}"
make build
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
install -Dm775 "${pkgname}" -t "${pkgdir}/usr/bin/"
install -Dm644 LICENSE \
-t "${pkgdir}/usr/share/licenses/${pkgname}"
install -D -m644 "${srcdir}/${pkgname}.conf" \
"${pkgdir}/etc/${pkgname}/${pkgname}.conf"
install -d "${pkgdir}/usr/share/${pkgname}/backends"
# systemd
install -D -m644 "${srcdir}/${pkgname}.service" \
-t "${pkgdir}/usr/lib/systemd/system"
install -D -m644 "${srcdir}/${pkgname}.sysusers" \
"${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
install -D -m644 "${srcdir}/${pkgname}.tmpfiles" \
"${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
}
sha256sums=('693d92fb5606c8c015ca5af8a03afc8474e888013ba5f293bd0db14b28db88fc'
'8153bc015f138655e08a49183c36d00f7fb661a2b9367110f44af844eab815ae'
'dd51cf954b60d75e0521a6e58188bcb06981e87d7ca8ac22d7dc4d46a362a671'
'97ba21355c50ec658e220bc0558f506227b3dc77cc51f343b6f5657b0d77a19b'
'6e4c0e2a2694867a5c27e21855e530a9327ae3658dbaa9b18fe028ab96df915a')
|