PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Slithery <aur at slithery dot uk>

pkgname=longview
pkgver=1.1.5
pkgrel=1
pkgdesc="A system monitoring agent for Linode customers."
arch=('any')
url="https://github.com/linode/$pkgname"
license=('GPL2')
depends=('perl-libwww' 'perl-crypt-ssleay' 'perl-io-socket-inet6'
         'perl-linux-distribution' 'perl-json-pp' 'perl-json'
         'perl-log-loglite' 'perl-try-tiny' 'perl-dbi')
optdepends=('perl-dbd-mysql: MySQL support')
backup=('etc/linode/longview.key'
        'etc/linode/longview.d/Apache.conf'
        'etc/linode/longview.d/MySQL.conf'
        'etc/linode/longview.d/Nginx.conf')
install=longview.install
source=($url/archive/v$pkgver.tar.gz)
sha256sums=('60a34af29e29e2c2640e7ee9dadd7771f78c6fb07f679a2887c1ddf704ca30ea')

build() {
    h2ph -d "$srcdir/$pkgname-$pkgver" /usr/include/syscall.h
    h2ph -d "$srcdir/$pkgname-$pkgver" /usr/include/sys/syscall.h
    h2ph -d "$srcdir/$pkgname-$pkgver" /usr/include/asm/unistd.h
    h2ph -d "$srcdir/$pkgname-$pkgver" /usr/include/asm/unistd_32.h
    h2ph -d "$srcdir/$pkgname-$pkgver" /usr/include/asm/unistd_64.h
    h2ph -d "$srcdir/$pkgname-$pkgver" /usr/include/bits/wordsize.h
    h2ph -d "$srcdir/$pkgname-$pkgver" /usr/include/bits/syscall.h
}

package() {
    cd "$pkgdir"
    install -d -m755 "opt/linode" "etc/linode/longview.d" "usr/lib/systemd/system"
    cp -dpr --no-preserve=ownership "$srcdir/$pkgname-$pkgver" "opt/linode/$pkgname"
    install -m600 -t "etc/linode/longview.d"  "opt/linode/$pkgname/Extras/conf/Apache.conf" \
                                              "opt/linode/$pkgname/Extras/conf/MySQL.conf"  \
                                              "opt/linode/$pkgname/Extras/conf/Nginx.conf"
    install -m644 -t "usr/lib/systemd/system" "opt/linode/$pkgname/Extras/init/longview.service"
    touch "etc/linode/longview.key"
    chmod 600 "etc/linode/longview.key"
    rm -rf "opt/linode/$pkgname/debian"      \
           "opt/linode/$pkgname/Extras/conf" \
           "opt/linode/$pkgname/Extras/init" \
           "opt/linode/$pkgname/Extras/install-dependencies.sh"
}