blob: 89734ad034dd03f15e5516d6a3a038babc2e6b22 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Nixuge
pkgname=lunar-client
_pkgname=lunarclient
pkgver=3.2.5
pkgrel=1
pkgdesc='PvP modpack for all modern versions of Minecraft'
url=https://lunarclient.com
arch=(x86_64)
license=(unknown)
depends=(fuse xorg-xrandr)
options=(!strip !debug)
_appimage="Lunar%20Client-${pkgver}.AppImage"
source=("https://launcherupdates.lunarclientcdn.com/${_appimage}")
sha256sums=('408dcfd1ce510f9ec6acca446de33d22d477e3252d1feaddd6a6ef1c411e4b3a')
prepare() {
chmod +x "${_appimage}"
./"${_appimage}" --appimage-extract
}
build() {
# Adjust .desktop so it will work outside of AppImage container
sed -i -E \
"s|Exec=AppRun|Exec=env DESKTOPINTEGRATION=false /usr/bin/${_pkgname}|" \
"squashfs-root/launcher.desktop"
# Fix permissions; .AppImage permissions are 700 for all directories
chmod -R a-x+rX squashfs-root/usr
}
package() {
# AppImage
install -Dm755 \
"${srcdir}/${_appimage}" \
"${pkgdir}/opt/${_pkgname}/${_pkgname}.AppImage"
# Desktop file
install -Dm644 \
"${srcdir}/squashfs-root/launcher.desktop" \
"${pkgdir}/usr/share/applications/${_pkgname}.desktop"
# Icon images
install -dm755 "${pkgdir}/usr/share/"
cp -a \
"${srcdir}/squashfs-root/usr/share/icons" \
"${pkgdir}/usr/share/"
# Symlink executable
install -dm755 "${pkgdir}/usr/bin"
ln -s \
"/opt/${_pkgname}/${_pkgname}.AppImage" \
"${pkgdir}/usr/bin/${_pkgname}"
}
# vim:set ts=4 sw=4 noet:
|